通达信大底量足主图指标公式

大底位置 := LLVBARS(L, 120);
大底周期 := BARSLAST(CURRBARSCOUNT = CONST(大底位置) + 1);
高点位置 := FINDHIGHBARS(H, 大底位置 + 1, 120, 1);
DRAWKLINE(H, O, L, C);
压力线: DRAWLINE(CURRBARSCOUNT = CONST(高点位置) + 1, H, ISLASTBAR, REF(H, 高点位置), 0), COLORFFFFFF, LINETHICK1;
高点周期 := BARSLAST(CURRBARSCOUNT = CONST(高点位置) + 1);
DRAWLINE(高点周期 = 0, H, 大底周期 = 0, L, 0), COLORFF8000, LINETHICK1;
黄金分割: DRAWLINE(大底周期 = 0, (压力线 - L) * 0.618 + L, ISLASTBAR, REF((压力线 - L) * 0.618 + L, 大底周期), 0), DOTLINE, COLORLIMAGENTA;
上涨量 := IF(C > O OR (C = O AND C >= REF(C, 1)), VOL, 0);
下跌量 := IF(C < O OR (C = O AND C < REF(C, 1)), VOL, 0);
量比系数 := SUM(上涨量, 大底周期) / SUM(下跌量, 大底周期);
信号出现 := COUNT(CROSS(C >= 压力线, 0.5), 大底周期 + 1) = 1  AND CROSS(C >= 压力线, 0.5) AND 量比系数 > 1.5;
DRAWICON(信号出现, L, 9);
DRAWTEXT(信号出现, L * 0.98, '量足'), COLORYELLOW;
STICKLINE(信号出现, C, O, 2, 0), COLORYELLOW;
STICKLINE(信号出现, H, L, 0, 0), COLORYELLOW;
DRAWTEXT(大底周期 = 0, L * 0.98, '大底形成'), COLORYELLOW;
突破周期 := BARSLAST(CROSS(C, REF(H, 高点周期)));
突破涨幅 := C / REF(H, 高点周期);
最大涨幅周期 := BARSLAST(突破涨幅 = HHV(突破涨幅, 突破周期 + 1));
跌幅统计 := (C - REF(C, 最大涨幅周期 + 1)) / REF(C, 最大涨幅周期 + 1) * 100;
价格比 := L / REF(H, 高点周期);
回踩条件 := 跌幅统计 < -8  AND 价格比 < 1.075  AND MIN(C, O) * 1.005 >= REF(H, 高点周期);
回踩信号 := BARSLAST(COUNT(回踩条件, 突破周期 + 1) = 1 AND 回踩条件);
回踩标记 := BACKSET(回踩信号 = 0, 最大涨幅周期 + 1);
信号起点 := BARSLAST(CROSS(回踩标记 = 1, 0.5));
未来跌幅 := REFX(跌幅统计, BARSNEXT(回踩信号 = 0));
DRAWICON(CROSS(回踩信号 = 0, 0.5), L * 0.99, 1);
DRAWTEXT(CROSS(回踩信号 = 0, 0.5), L * 0.980, '回踩'), COLORYELLOW;
DRAWLINE(突破周期 = 0, REF(H, 高点周期), 信号起点 = 0, REF(H, 信号起点), 0), DOTLINE, COLORYELLOW;
DRAWLINE(信号起点 = 0, REF(H, 信号起点), 回踩信号 = 0, REF(H, 高点周期), 0), DOTLINE, COLORYELLOW;
DRAWTEXT(高点周期 = 0, REF(H, 高点周期) * 1.05, 
       VARCAT(VARCAT('压力价：', VAR2STR(REF(H, 高点周期), 2)), '元')), COLORYELLOW;
DRAWLINE(信号起点 = 0, REF(H, 信号起点) * 1.05, 信号起点 = 10, REF(H, 信号起点) * 1.05, 0), COLORWHITE, LINETHICK3;
DRAWTEXT(信号起点 = 0, REF(H, 信号起点) * 1.01, 
 VARCAT(VARCAT('信号处跌幅：', VAR2STR(未来跌幅, 2)), '%')), COLORYELLOW;
STICKLINE(C / REF(C, 1) >= 1.092, O, C, 3.1, 0), COLORYELLOW;
STICKLINE(C / REF(C, 1) <= 0.9008, O, C, 3.1, 0), COLORBLUE;