N周期:=27;
动量RSV:=(CLOSE-LLV(LOW,N周期))/(HHV(HIGH,N周期)-LLV(LOW,N周期))*100;
动量K:=SMA(动量RSV,5,1);
动量D:=SMA(动量K,3,1);
动量趋势:=3*动量K - 2*动量D;
底部警戒:=10,COLORRED,LINETHICK2;
底1信号:=CROSS(动量趋势,底部警戒);
加权价:=(2*CLOSE+HIGH+LOW)/4;
近期低:=LLV(LOW,N周期);
近期高:=HHV(HIGH,N周期);
摆动线:=EMA((加权价-近期低)/(近期高-近期低)*100,13);
信号线:=EMA(0.618*REF(摆动线,1)+0.382*摆动线,3);
底2信号:=CROSS(摆动线,信号线) AND 摆动线<16;
波段底:=底1信号 AND 底2信号;
短动量:=(CLOSE-LLV(LOW,20))/(HHV(HIGH,20)-LLV(LOW,20))*100;
短K:=SMA(SMA(短动量,3,1),3,1)/28.57;
短D:=EMA(短K,5);
短J:=3*短K - 2*短D;
牛信号:=CROSS(短J,短K) AND 短K<2.1 AND C>O;
动周期:=10;
动高:=HHV(HIGH,25);
动低:=LLV(LOW,动周期);
动力线:=EMA((CLOSE-动低)/(动高-动低)*4,4);
N:=19;
阻高:=HHV(HIGH,N);
阻低:=LLV(LOW,N);
阻力线:=EMA((CLOSE-阻低)/(阻高-阻低),21)-0.5;
操作线:=EMA((CLOSE-阻低)/(阻高-阻低),5)-0.5;
突破信号:=CROSS(操作线,阻力线) AND 阻力线<0.1;
破位信号:=CROSS(阻力线,操作线) AND 阻力线>0.25;

{ 放量识别 }
V率:=IF(CURRBARSCOUNT=1,VOL*240/FROMOPEN/REF(VOL,1)-1,VOL/REF(VOL,1)-1);
放量:=V率>=1;
放量位置:=BARSLAST(放量);
前低点:=REF(L,放量位置);
前高点:=REF(H,放量位置);
L1:=MIN(REF(L,1),L);
L2:=MIN(L1,REF(L,2));
H1:=MAX(REF(H,1),H);
H2:=MAX(H1,REF(H,2));
反弹确认:=(REF(放量,3) OR REF(放量,2) OR REF(放量,1)) AND ((L2>前低点 AND H2>前高点) OR (L1>前低点 AND H1>前高点) OR (L>前高点));
T11信号:=反弹确认 AND REF(反弹确认,1)=0;
{ 涨跌停判断 }
昨收:=REF(C,1);
涨停:=IF((C-昨收)*100/昨收 >= (10-0.01*100/昨收),1,0);
跌停:=IF((昨收-C)*100/昨收 >= (10-0.01*100/昨收),1,0);
{ RSI 背离 }
LC:=REF(CLOSE,1);
RSI:=(SMA(MAX((CLOSE - LC),0),3,1) / SMA(ABS((CLOSE - LC)),3,1)) * 100;
顶背离:=CROSS(88,RSI);
底背离:=CROSS(EMA(C,3),EMA(C,21));
{ 走势角度 }
X1:=(3*C+L+H+O)/6;
角度:=ATAN(EMA(X1,13)-REF(EMA(X1,13),1))*3.1416*10;
EMA8:=EMA(C,8);
角度信号:=FILTER(角度>1 AND EMA(X1,13)>REF(EMA(X1,8),1),10);
{ 获利盘 }
获利盘:=WINNER(C)*100;
{ 成交量主图 }
VOLUME:VOL,VOLSTICK;
MAVOL1:=MA(VOLUME,5),COLORWHITE;
MAVOL2:=MA(VOLUME,35),COLORYELLOW;
MAVOL3:=MA(VOLUME,135),COLORGREEN;
{ 绘图区 }
{ 1. 放量柱 }
STICKLINE(放量,0,VOL*0.5,2,0),COLORYELLOW;
{ 2. 动力线强 }
STICKLINE(动力线>=3.2,0,VOL,1,0),COLOR238E23;
{ 3. 波段底 }
STICKLINE(波段底,0,VOL,2,0),COLORMAGENTA;
DRAWTEXT(波段底,VOL*0.8,'底'),COLORWHITE;
DRAWICON(波段底,VOL*1.1,5);
{ 4. 牛信号 }
STICKLINE(牛信号,0,VOL,2,0),COLORRED;
DRAWTEXT(牛信号,VOL*1.15,'牛'),COLORWHITE;
{ 5. 突破 }
STICKLINE(突破信号,0,VOL,1,0),COLORBLUE;
DRAWTEXT(突破信号,VOL*0.5,'突破'),COLORWHITE;
DRAWICON(突破信号,VOL*1.2,1);
{ 6. 破位 }
STICKLINE(破位信号,0,VOL,0.5,0),COLORBROWN;
DRAWTEXT(破位信号,VOL*0.5,'破位'),COLORWHITE;
DRAWICON(破位信号,VOL*1.05,2);
{ 7. 反弹确认 }
STICKLINE(T11信号,O,VOL,2,0),COLORFF00FF;
{ 8. 涨停 }
STICKLINE(涨停,VOL*0.5,VOL,2.5,0),COLORLIRED;
STICKLINE(涨停,VOL*0.5,VOL,0,0),COLORRED;
{ 9. 跌停 }
STICKLINE(跌停,VOL*0.5,VOL,2.5,0),COLOR2F4F2F;
STICKLINE(跌停,VOL*0.5,VOL,0,0),COLORBLACK;
{ 10. 背离 }
STICKLINE(顶背离,VOL*0.8,VOL,2.5,0),COLORGREEN;
STICKLINE(底背离,0,VOL*0.2,3,0),COLOR7F017F;

{ 11. 角度提示 }
DRAWTEXT(角度信号,VOL*1.1,'∠45'),COLOR00F3F5;
{ 12. 获利盘提示 }
DRAWTEXT(获利盘>=90 AND 动力线>=3.2,VOL*1.1,'获利90●'),COLORRED;
DRAWTEXT(获利盘<75 AND 动力线>=3.2,VOL*1.1,'●'),COLORGREEN;
{ 13. 逃顶信号 }
VAR1:=(HHV(HIGH,9)-CLOSE)/(HHV(HIGH,9)-LLV(LOW,9))*100-70;
动量6:=SMA(MAX(CLOSE-REF(C,1),0),6,1)/SMA(ABS(CLOSE-REF(C,1)),6,1)*100;
DRAWTEXT(CROSS(82,动量6) OR CROSS(82,RSI),VOL*1.2,'逃'),COLOR22FF33;
{ 14. 短线MACD }
短DIF:=(EMA(CLOSE,5)-EMA(CLOSE,21))*4,COLORFFFFFF;
短DEA:=EMA(短DIF,5),COLOR00FFFF;
MMD:=2*(短DIF-短DEA);
DRAWICON(CROSS(短DIF,短DEA) AND 短DIF<=0.08,短DIF,1);
DRAWICON(CROSS(短DEA,短DIF) AND 短DIF>=0.09,短DEA*1.05,2);
{ 16. K线形态识别 }
VAR10:=C=HHV(C,4) AND REF(C,1)=LLV(C,4);
VAR20:=C=LLV(C,4) AND (REF(C,1)<REF(C,2) OR REF(C,1)<REF(C,3)) OR REF(C,1)=LLV(C,4) AND C<REF(C,2) OR REF(C,2)=LLV(C,4) AND REF(C,1)=HHV(C,4) AND C<REF(C,1) OR REF(C,3)=LLV(C,4) AND C<REF(C,1) AND C<REF(C,2);
VAR30:=REF(C,1)=LLV(C,4) AND C>=REF(C,2) OR REF(C,2)=LLV(C,4) AND REF(C,1)<=REF(C,3) AND REF(C,2)<REF(C,4) AND C>=REF(C,1);
{ 17. 加权均线 }
加权均线:=(20*X1+19*REF(X1,1)+18*REF(X1,2)+17*REF(X1,3)+16*REF(X1,4)+15*REF(X1,5)+14*REF(X1,6)+13*REF(X1,7)+12*REF(X1,8)+11*REF(X1,9)+10*REF(X1,10)+9*REF(X1,11)+8*REF(X1,12)+7*REF(X1,13)+6*REF(X1,14)+5*REF(X1,15)+4*REF(X1,16)+3*REF(X1,17)+2*REF(X1,18)+REF(X1,20))/210;
MTM:=C-REF(C,1);
DX:=100*EMA(EMA(MTM,6),6)/EMA(EMA(ABS(MTM),6),6);
CB均线:=EMA(加权均线,13);
MA130:MA(VOL,13),COLORE011FF,LINETHICK3;
{ 变异均线 }
变异:=IF(MA(X1,13)>MA(X1,5),MA(VOL,13),DRAWNULL),COLOR00FF00,LINETHICK3;
{ 卖出信号 }
卖信号:=HHV(DX,2)=HHV(DX,7) AND COUNT(DX>50,2) AND CROSS(MA(DX,2),DX);
DRAWTEXT(FILTER(卖信号=1,1),VOL*1.02,'卖'),COLORGREEN;
{ 买入信号 }
买信号:=LLV(DX,2)=LLV(DX,7) AND COUNT(DX<0,2) AND CROSS(DX,MA(DX,2));
DRAWTEXT(FILTER(买信号=1,5),VOL*1.13,'买'),COLORRED;
{ 加仓信号 }
加仓动量:=SMA(EMA((C-REF(C,1))/REF(C,1),5)*100,3,1)*10;
加仓信号:=(CROSS(加仓动量,0) OR CROSS(CLOSE,CB均线)) AND 买信号=1;
DRAWTEXT(FILTER(加仓信号,3),VOL*1.05,'加'),COLORWHITE;
{ 跟进信号 }
趋势向上:=MA(X1,18)>=REF(MA(X1,18),3) AND CROSS(CLOSE,MA(X1,18));
DRAWTEXT(趋势向上,VOL*1.06,'跟'),COLORCC66FF;

指标公式逻辑介绍